Top ads at egroups.com

[Skip Huffman]

On Fri, 15 Sep 2000 23:43:58 -0700 (PDT), Steve Wendt wrote:

>On Fri, 15 Sep 2000, Skip Huffman wrote:
>
>> Topica.  Egroups used to be, but then "Son of Borg" (Yahoo)
>> assimilated them.
>
>I guess that explains the massive influx of spam on the egroups lists
>recently, at the top of every message.  :(

Here, this will put the ads back at the bottom.  Just dump this into a Rexx command file(watch
 your word wrap), (use Regina if you run windows) and create a filter looking for 
'h.Reply-To="egroups.com"' to call it:


/* Strip Ads from Egroups messages */

StartKey="-------------------------- eGroups Sponsor -------------------------~-~>"
EndKey  ="---------------------------------------------------------------------_->"

Parse Arg FileName /* Get the message filename that is passed by PMMail*/


InIndex=0
do while Lines(filename)>0
   InIndex=InIndex+1
   LineBuffer.InIndex=LineIn(FileName)
end /* do */

rc=LineOut(FileName) /* Close the file */

/**********************************************/
/*Write the buffers back to the message file. */
/**********************************************/
EndIndex=0
RC=LineOut(FileName,LineBuffer.1,1) /* Write the first line and reset the write pointer. */
do OutIndex=2 to InIndex
   if Strip(LineBuffer.OutIndex,," ")<>StartKey
   then RC=LineOut(FileName,LineBuffer.OutIndex)
   else do
           do Until Strip(LineBuffer.OutIndex,," ")=EndKey
              endindex=endindex+1
              EndBuffer.EndIndex=LineBuffer.OutIndex
              OutIndex=OutIndex+1
           end /* do */
           endindex=endindex+1
           EndBuffer.EndIndex=LineBuffer.OutIndex
        end /* do */

end /* do */
if EndIndex>0 
then do i=1 to EndIndex
        RC=LineOut(FileName,EndBuffer.I) 
     end /* do */

rc=LineOut(FileName) /* Close the file again. */

exit



__________________________________________________
Do You Yahoo!?
Talk to your friends online with Yahoo! Messenger.
http://im.yahoo.com