[pmmail-list] turn on return receipt by default

[Paul Ratcliffe]

On Tue, 31 Jul 2001 22:11:56 -0500, Scott E. Garfinkle wrote:

>>No. If you were running OS/2, I could supply a REXX hook script to do it...
>Well, just in case I ever want to do it at work, what would that look like?

Like this:

/* REXX Message Send exit to add return receipt request to all messages */
/* Configure the email address to use for the receipts on the next line */
email = 'user@domain'
/**/
arg file
inhdr = 1
i = 0
modflag = 0
gotrr = 0
do while lines(file) <> 0
  i = i + 1
  line.0 = i
  line.i = linein(file)
  if inhdr = 1 then
    if length(line.i) = 0 then do
      inhdr = 0
      if gotrr = 0 then do
	line.i = 'Return-Receipt-To:' email
	i = i + 1
	line.0 = i
	line.i = ''
	modflag = 1
      end
    end; else if left(line.i, 18) = 'Return-Receipt-To:' then
      gotrr = 1
end
call stream file, 'C', 'CLOSE'
if modflag = 1 then do
  '@del' file '2>nul'
  do i = 1 to line.0
    call lineout file, line.i
  end
  call lineout file
end

- pmmail-list - The PMMail Dicussion List ---------------------------
To UNSUBSCRIBE, send a message to mdaemon@bmtmicro.com with the first 
line of the message body being...
UNSUBSCRIBE pmmail-list@blueprintsoftwareworks.com